ruby-em-proxy/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _gemname=em-proxy
   4 pkgname=ruby-${_gemname}
   5 pkgver=0.1.9
   6 pkgrel=7
   7 pkgdesc='EventMachine Proxy DSL for writing high-performance transparent / intercepting proxies'
   8 url='https://github.com/igrigorik/em-proxy'
   9 arch=('any')
  10 license=('MIT')
  11 depends=('ruby' 'ruby-eventmachine')
  12 options=('!emptydirs')
  13 source=(${pkgname}-${pkgver}.tar.gz::https://github.com/igrigorik/em-proxy/archive/v${pkgver}.tar.gz)
  14 sha512sums=('722b5010c8de9a809016b330e2123dc3bfb61e0c497844babb3af283e166271c00d74d58ca24c14e02b89346c114a2fd516a62ea00d5efe75981785719ad48e6')
  15
  16 prepare() {
  17   cd ${_gemname}-${pkgver}
  18   sed 's|git ls-files|find|' -i ${_gemname}.gemspec
  19 }
  20
  21 build() {
  22   cd ${_gemname}-${pkgver}
  23   gem build ${_gemname}.gemspec
  24 }
  25
  26 package() {
  27   cd ${_gemname}-${pkgver}
  28   local _gemdir="$(gem env gemdir)"
  29   gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
  30   install -Dm 644 README.md CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  31   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  32   cp -r examples "${pkgdir}/usr/share/doc/${pkgname}"
  33   rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"
  34 }
  35
  36 # vim: ts=2 sw=2 et: