ruby-mini_portile/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _gemname=mini_portile
   4 pkgname=ruby-${_gemname}
   5 pkgver=0.6.2
   6 pkgrel=4
   7 pkgdesc='Simple autoconf builder for developers'
   8 url='https://github.com/flavorjones/mini_portile'
   9 arch=('any')
  10 license=('MIT')
  11 depends=('ruby')
  12 makedepends=('ruby-rdoc' 'ruby-rake')
  13 options=('!emptydirs')
  14 source=(https://github.com/flavorjones/mini_portile/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz)
  15 sha256sums=('359feeb4c18f172ea4eafc0ef0646b85787a6ce210733c6a58b85d54b46f4a13')
  16 sha512sums=('7b9bd79d42af9aa146c21b59d1beaad623e0f981b8d849653e3f2f8bb69d986ffbf0661bf0867cb1ce0aee48ca6ff613b9e9f1cc4b280d85b27e9c8195d48a24')
  17
  18 build() {
  19   cd ${_gemname}-${pkgver}
  20   rake gem
  21 }
  22
  23 package() {
  24   cd ${_gemname}-${pkgver}
  25   local _gemdir="$(gem env gemdir)"
  26   gem install --ignore-dependencies --no-user-install -i "${pkgdir}${_gemdir}" \
  27     -n "${pkgdir}/usr/bin" pkg/${_gemname}-${pkgver}.gem
  28
  29   install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  30   install -Dm 644 README.rdoc History.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
  31   install -Dm 644 examples/* -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
  32
  33   rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"
  34 }
  35
  36 # vim: ts=2 sw=2 et: