ruby-mini_portile2/repos/community-any/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>
   3 # Contributor: Dmitry Kharitonov <darksab0r@gmail.com>
   4 # Contributor: Anatol Pomozov <anatol.pomozov@gmail.com>
   5 # Contributor: eagletmt <eagletmt@gmail.com>
   6
   7 _gemname='mini_portile2'
   8 pkgname="ruby-${_gemname}"
   9 pkgver=2.8.0
  10 pkgrel=1
  11 pkgdesc='Simple autoconf builder for developers'
  12 url='https://github.com/flavorjones/mini_portile'
  13 arch=('any')
  14 license=('MIT')
  15 depends=('ruby')
  16 makedepends=('ruby-rdoc')
  17 options=('!emptydirs')
  18 source=("https://github.com/flavorjones/mini_portile/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
  19 sha256sums=('33285113315568cbd67659a09b0c596f061517a20bd5c33676810ed02836c2cd')
  20 sha512sums=('c30d9387ee206dc1ef52b779a1e66e3c8a4247bea94009741911246371a74aebbe27c6f92cacc4a74c064fdaac3cec8e926232467377ad5c0fe501629e623b10')
  21
  22 prepare() {
  23   cd "mini_portile-${pkgver}"
  24
  25   sed -r 's|~>|>=|g' -i "${_gemname}.gemspec"
  26   sed 's|git ls-files -z|find -type f -print0|' -i "${_gemname}.gemspec"
  27 }
  28
  29 build() {
  30   cd "mini_portile-${pkgver}"
  31
  32   gem build "${_gemname}.gemspec"
  33 }
  34
  35 package() {
  36   cd "mini_portile-${pkgver}"
  37
  38   local _gemdir="$(gem env gemdir)"
  39
  40   gem install --ignore-dependencies --no-user-install -i "${pkgdir}${_gemdir}" -n "${pkgdir}/usr/bin" "${_gemname}-${pkgver}.gem"
  41
  42   rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"
  43
  44   install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  45   install -Dm 644 README.md CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  46 }
  47
  48 # vim: ts=2 sw=2 et: