ruby-minitest-sprint/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _gemname=minitest-sprint
   4 pkgname=ruby-${_gemname}
   5 pkgver=1.2.2
   6 pkgrel=1
   7 pkgdesc="Runs (Get it? It's fast!) your tests and makes it easier to rerun individual failures"
   8 url='https://github.com/seattlerb/minitest-sprint'
   9 arch=('any')
  10 license=('MIT')
  11 depends=('ruby' 'ruby-minitest' 'ruby-path_expander')
  12 makedepends=('ruby-rdoc' 'ruby-rake' 'ruby-hoe')
  13 options=('!emptydirs')
  14 source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  15 sha512sums=('3c2d815978e03b25530497946fe193b12edba83df621418c30833a2ee7e02e7be40e9f6ac11954bfca65606745cdeaa38a781976aea7de7621ed07d9b0f15fb5')
  16 b2sums=('342db7ca15e0351abdbed58dd0d037a40883c913fb8042ec1a3eca328efa4cf9dff24628e957db54c3bc9468a0cd90a723874de5bcd5eeb59053952a6ee7ebac')
  17
  18 build() {
  19   cd ${_gemname}-${pkgver}
  20   sed -r 's|~>|>=|g' -i Rakefile
  21   rake gem
  22 }
  23
  24 check() {
  25   cd ${_gemname}-${pkgver}
  26   rake test
  27 }
  28
  29 package() {
  30   cd ${_gemname}-${pkgver}
  31   local _gemdir="$(gem env gemdir)"
  32   gem install --ignore-dependencies --no-user-install -i "${pkgdir}${_gemdir}" \
  33     -n "${pkgdir}/usr/bin" pkg/${_gemname}-${pkgver}.gem
  34
  35   install -Dm 644 README.rdoc History.rdoc -t "${pkgdir}/usr/share/doc/${pkgname}"
  36   install -Dm 644 README.rdoc -t "${pkgdir}/usr/share/licenses/${pkgname}"
  37
  38   rm -r "${pkgdir}/${_gemdir}/"{cache,gems/${_gemname}-${pkgver}/test}
  39 }
  40
  41 # vim: ts=2 sw=2 et: