ruby-packetfu/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _gemname=packetfu
   4 pkgname=ruby-${_gemname}
   5 pkgver=1.1.13
   6 pkgrel=5
   7 pkgdesc='Library for reading and writing packets to an interface or to a libpcap-formatted file'
   8 url='https://github.com/packetfu/packetfu'
   9 arch=('any')
  10 license=('BSD')
  11 depends=('ruby' 'ruby-network_interface' 'ruby-pcaprub')
  12 makedepends=('ruby-rake' 'ruby-rdoc')
  13 options=('!emptydirs')
  14 source=(${pkgname}-${pkgver}.tar.gz::https://github.com/packetfu/packetfu/archive/version-${pkgver}.tar.gz)
  15 sha256sums=('323add3c94b869c48c9f20ecacc0d176c9a0d1a47f606ebaa15105f5c9a9d828')
  16 sha512sums=('2e8f2e05b15cf5e9007384ff55dfa6dad9a8f9d32f86b8d05dd4df930f72bd9fa80a84a5f465c936fca5615f87cd6129a0edad0863ef4eca15c5d970390d62a0')
  17
  18 prepare() {
  19   cd ${_gemname}-version-${pkgver}
  20   sed 's|git ls-files|find|' -i ${_gemname}.gemspec
  21   sed -r 's|~>|>=|g' -i ${_gemname}.gemspec
  22 }
  23
  24 build() {
  25   cd ${_gemname}-version-${pkgver}
  26   gem build ${_gemname}.gemspec
  27 }
  28
  29 package() {
  30   cd ${_gemname}-version-${pkgver}
  31   local _gemdir="$(gem env gemdir)"
  32   gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
  33   install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  34   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  35   install -Dm 644 examples/* -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
  36 }
  37
  38 # vim: ts=2 sw=2 et: