ruby-rainbow/repos/community-any/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Hyacinthe Cartiaux <hyacinthe.cartiaux AT free DOT fr>
   3 # Contributor: Juan Diego Tascon
   4 # Contributor: Tom Vincent <http://tlvince.com/contact/>
   5
   6 _gemname=rainbow
   7 pkgname=ruby-${_gemname}
   8 pkgver=3.1.1
   9 pkgrel=1
  10 pkgdesc="Rainbow is extension to ruby's String class adding support for colorizing text on ANSI terminal"
  11 url='https://rubygems.org/gems/rainbow'
  12 arch=('any')
  13 license=('MIT')
  14 depends=('ruby' 'ruby-rdoc')
  15 options=('!emptydirs')
  16 source=(${pkgname}-${pkgver}.tar.gz::https://github.com/sickill/rainbow/archive/v${pkgver}.tar.gz)
  17 sha256sums=('8ede18d7eb85a84c5c61d0136ca3715a2ff9150010cba9164f802e966c05f837')
  18 sha512sums=('5aff955e8baf78d99960ec9caa11626f07460085f35966c410bb867dd6454a932d2ee8742729a32eeca186fa338bbb02bce3ee8a452a8b4fb0044bb6ec751bc3')
  19
  20 prepare() {
  21   cd ${_gemname}-${pkgver}
  22   sed -r 's|~>|>=|g' -i rainbow.gemspec # don't give a fuck about rubys bla bla
  23   sed -r 's|git ls-files|find|g' -i rainbow.gemspec
  24 }
  25
  26 build() {
  27   cd ${_gemname}-${pkgver}
  28   gem build rainbow.gemspec
  29 }
  30
  31 package() {
  32   cd ${_gemname}-${pkgver}
  33   local _gemdir="$(gem env gemdir)"
  34   gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" -n "${pkgdir}/usr/bin" rainbow*.gem
  35   install -Dm 644 README.markdown Changelog.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  36   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  37   rm "${pkgdir}"/${_gemdir}/cache/${_gemname}-${pkgver}.gem
  38 }
  39
  40 # vim: ts=2 sw=2 et: