ruby-rouge/repos/community-any/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _gemname=rouge
   4 pkgname=ruby-rouge
   5 pkgver=4.1.0
   6 pkgrel=1
   7 pkgdesc='Pure-ruby code highlighter that is compatible with pygments'
   8 url='http://rouge.jneen.net/'
   9 arch=('any')
  10 license=('MIT')
  11 depends=('ruby' 'ruby-rdoc')
  12 options=('!emptydirs')
  13 source=(https://github.com/jneen/rouge/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  14 sha512sums=('02bcdcf57d3eb896a006513439930791e4a7486c83e1124fff8d8d2abe211d151b238b52dac1a14019dfed061a44ab249ce7979b94602df730c5684522320252')
  15 b2sums=('4cbff8d855d36e2d4ab79bc7c125eb2e757f11dabfc5501f59687d7203d3ca1ac503a44caa938de05a99676b4fbe885dd7c012139dbbbfe110d5409e7d3ffc1a')
  16
  17 prepare() {
  18   cd ${_gemname}-${pkgver}
  19   sed -r 's|~>|>=|g' -i ${_gemname}.gemspec
  20 }
  21
  22 build() {
  23   cd ${_gemname}-${pkgver}
  24   gem build ${_gemname}.gemspec
  25 }
  26
  27 package() {
  28   cd ${_gemname}-${pkgver}
  29   local _gemdir="$(gem env gemdir)"
  30   gem install --ignore-dependencies --no-user-install -i "${pkgdir}${_gemdir}" -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
  31   install -Dm 644 README.md CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  32   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  33   rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"
  34 }
  35
  36 # vim: ts=2 sw=2 et: