ruby-tins/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: Maxime Gauduin <alucryd@archlinux.org>
   3 # Contributor: Julien Nicoulaud <julien.nicoulaud@gmail.com>
   4 # Contributor: Hyacinthe Cartiaux <hyacinthe.cartiaux@free.fr>
   5
   6 pkgname=ruby-tins
   7 _pkgname="${pkgname#ruby-}"
   8 pkgver=1.32.1
   9 pkgrel=1
  10 pkgdesc='All the stuff that is not good/big enough for a real library'
  11 arch=('any')
  12 url='https://github.com/flori/tins'
  13 license=('MIT')
  14 depends=('ruby' 'ruby-sync')
  15 makedepends=('git' 'ruby-rake')
  16 options=('!emptydirs')
  17 _commit='6e1d4309ae4bd0e7b0e21280336732a2f51311e2'
  18 source=("$pkgname::git+$url#commit=$_commit")
  19 b2sums=('SKIP')
  20
  21 pkgver() {
  22   cd "$pkgname"
  23
  24   git describe --tags | sed 's/^v//'
  25 }
  26
  27 build() {
  28   cd "$pkgname"
  29
  30   gem build tins.gemspec
  31 }
  32
  33 package() {
  34   cd "$pkgname"
  35
  36   local _gemdir="$(ruby -e'puts Gem.default_dir')"
  37
  38   gem install \
  39     --local \
  40     --verbose \
  41     --ignore-dependencies \
  42     --no-user-install \
  43     --install-dir "$pkgdir/$_gemdir" \
  44     --bindir "$pkgdir/usr/bin" \
  45     "$_pkgname-$pkgver.gem"
  46
  47   # delete cache
  48   rm -rf "$pkgdir/$_gemdir/cache"
  49
  50   # license
  51   install -vd "$pkgdir/usr/share/licenses/$pkgname"
  52   ln -sf "$_gemdir/gems/$_pkgname-$pkgver/COPYING" "$pkgdir/usr/share/licenses/$pkgname"
  53 }