sc3-plugins/repos/community-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2
   3 pkgname=sc3-plugins
   4 pkgver=3.13.0
   5 pkgrel=1
   6 pkgdesc="Extension plugins for the SuperCollider3 audio synthesis server."
   7 arch=(x86_64)
   8 url="https://github.com/supercollider/sc3-plugins"
   9 license=(GPL2)
  10 groups=(pro-audio)
  11 depends=(gcc-libs glibc supercollider)
  12 makedepends=(cmake fftw stk)
  13 source=("https://github.com/supercollider/${pkgname}/releases/download/Version-${pkgver}/${pkgname}-${pkgver}-Source.tar.bz2"{,.asc})
  14 sha512sums=('4a89bb7d76d60983a8c5ea6560dc9993f585e7dc47593adc2686b772cdb7649423e2cf2c170340c0c7ee16d4a6348877a6572faacfc593a9075da60b9a06988f'
  15             'SKIP')
  16 b2sums=('55e34ff7cdae5ef48199c529e2a55c72fcb4c462d5e6f0001513e0b0d9b9e902f3e117e10fe9063b1e0f22d8d950e087059f2ca8bf1d4d794302d6dda22326bd'
  17         'SKIP')
  18 validpgpkeys=(
  19     '0B7D1EA4E32B5C3C4275D3C70796CC538BEFF177' # Brian Heim <self@brianlheim.com>
  20     '2E1C4FC2F6BB58FA157B21B8064B501EB7405F04' # Marcin Paczkowski <marcin.piotr.paczkowski@gmail.com>
  21 )
  22
  23 prepare() {
  24   mv -v "$pkgname-$pkgver-Source" "${pkgname}-${pkgver}"
  25 }
  26
  27 build() {
  28   cd "$pkgname-$pkgver"
  29   cmake -DCMAKE_INSTALL_PREFIX=/usr \
  30         -DCMAKE_BUILD_TYPE=None \
  31         -DSC_PATH=/usr/include/SuperCollider/ \
  32         -DSYSTEM_STK=ON \
  33         -DSUPERNOVA=ON \
  34         -W no-dev \
  35         -B build \
  36         -S .
  37   make VERBOSE=1 -C build
  38 }
  39
  40 package() {
  41   depends+=(libfftw3f.so libstk-4.6.2.so)
  42
  43   cd "$pkgname-$pkgver"
  44   make VERBOSE=1 DESTDIR="$pkgdir/" install -C build
  45   install -vDm 644 {{DEVELOPING,README}.md,TODO} -t "${pkgdir}/usr/share/doc/${pkgname}/"
  46 }