scenarist/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: cyrant <cyrant at tuta dot io>
   3
   4 pkgname=scenarist
   5 pkgver=0.7.2.rc15
   6 pkgrel=1
   7 pkgdesc='Screenwriting software to create screenplays which oriented at international standards in the field of film production'
   8 arch=('x86_64')
   9 url='https://kitscenarist.ru/en/'
  10 license=('GPL3')
  11 depends=('hunspell' 'qt5-multimedia' 'qt5-svg' 'qt5-webengine')
  12 makedepends=('git')
  13 _commit=70ebff68c67242ee4f9a5d1f6397f00d0dd471ff
  14 source=("git+https://github.com/dimkanovikov/KITScenarist.git#commit=$_commit"
  15         'git+https://github.com/dimkanovikov/KITScenaristCore.git'
  16         'scenarist.mime.xml'
  17         'scenarist.appdata.xml')
  18 sha256sums=('SKIP'
  19             'SKIP'
  20             '513987794f8ba5a4c12aa2a65314fccdc098f86e616a416977aead29e6545b63'
  21             'ae04ebca48b01ef86d913f769ff856e259e7c3f13a75fc4e05cc15487460772b')
  22
  23 pkgver() {
  24   cd KITScenarist
  25   git describe --tags | sed 's/-/+/g'
  26 }
  27
  28 prepare() {
  29   cd KITScenarist
  30   git submodule init
  31   git submodule set-url src/bin/scenarist-core "$srcdir/KITScenaristCore"
  32   git submodule update
  33
  34   # Use system hunspell
  35   sed -i '/hunspell/d
  36           s/LIBS += -lz/LIBS += -lhunspell -lz/' src/bin/scenarist-desktop.pro \
  37                                                  src/libs/libs.pro
  38 }
  39
  40 build() {
  41   cd KITScenarist/src
  42   qmake-qt5
  43   make
  44 }
  45
  46 package() {
  47   cd KITScenarist
  48   install -Dm755 build/Release/bin/scenarist-desktop/Scenarist "$pkgdir/usr/bin/$pkgname"
  49   install -Dm644 build/Ubuntu/scenarist_amd64/usr/share/applications/$pkgname.desktop "$pkgdir/usr/share/applications/$pkgname.desktop"
  50   install -Dm644 build/Ubuntu/scenarist_amd64/usr/share/pixmaps/$pkgname.png "$pkgdir/usr/share/icons/hicolor/512x512/apps/$pkgname.png"
  51   install -Dm644 ../$pkgname.mime.xml "$pkgdir/usr/share/mime/packages/$pkgname.xml"
  52   install -Dm644 ../$pkgname.appdata.xml "$pkgdir/usr/share/metainfo/$pkgname.appdata.xml"
  53 }