sndio/trunk/PKGBUILD

   1 # Maintainer: Ivy Foster <iff@archlinux.org>
   2 # Reference: PKGBUILD(5)
   3
   4 pkgname=sndio
   5 pkgver=1.9.0
   6 pkgrel=1
   7 pkgdesc='A small audio and MIDI framework part of the OpenBSD project'
   8 arch=(x86_64)
   9 url='https://sndio.org'
  10 license=(ISC)
  11
  12 # sndio can be built without libbsd, but there are a bunch of individual
  13 # ISC-licensed files by different authors to extract the licenses from
  14 # if done that way. Licenses are complicated.
  15 depends=(alsa-lib libbsd)
  16
  17 provides=(libsndio.so)
  18
  19 source=(
  20         "https://sndio.org/sndio-$pkgver.tar.gz"
  21         "https://sndio.org/sndio-$pkgver.tar.gz.asc"
  22 )
  23 # Checksum source: https://www.sndio.org/sndio-$pkgver.tar.gz.sha256
  24 sha256sums=(
  25         f30826fc9c07e369d3924d5fcedf6a0a53c0df4ae1f5ab50fe9cf280540f699a
  26         SKIP
  27 )
  28 validpgpkeys=(6B1A7447AAF091CCDD36BAA6015E339411694A6E)
  29
  30 backup=(etc/default/sndiod)
  31
  32 build() {
  33         cd "sndio-$pkgver"
  34         ./configure --prefix=/usr --enable-alsa --with-libbsd
  35         make
  36 }
  37
  38 package() {
  39         cd "sndio-$pkgver"
  40
  41         make DESTDIR="$pkgdir/" install
  42
  43         install -D -m 644 contrib/sndiod.service \
  44                 "$pkgdir/usr/lib/systemd/system/sndiod.service"
  45         install -D -m 644 contrib/default.sndiod \
  46                 "$pkgdir/etc/default/sndiod"
  47
  48         install -d "$pkgdir/usr/share/licenses/sndio"
  49         # this is the most up-to-date license outside of bsd-compat,
  50         # which isn't being used in this build
  51         sed '/^ \*\//q' libsndio/sioctl.c > "$pkgdir/usr/share/licenses/sndio/LICENSE"
  52 }