sparkleshare/trunk/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: Jarek Sedlacek <JarekSedlacek@gmail.com>
   3 # Contributor: Erdbeerkaese <erdbeerkaese underscore arch at gmail dot com>
   4
   5 pkgname=sparkleshare
   6 _pkgname=SparkleShare
   7 pkgver=3.38
   8 pkgrel=1
   9 pkgdesc="Collaboration and sharing tool based on git written in C Sharp"
  10 arch=('any')
  11 url="https://www.sparkleshare.org/"
  12 license=('GPL3')
  13 depends=('webkit2-sharp' 'notify-sharp-3' 'curl' 'git-lfs' 'openssh' 'gvfs')
  14 makedepends=(git meson)
  15 _commit=23d7166012e6fcf9ad6b6d317217908bbc0f51c8
  16 source=("git+https://github.com/hbons/SparkleShare.git#commit=$_commit"
  17         "0001-Use-gtk-status-icon-by-default.patch")
  18 sha256sums=('SKIP'
  19             '6565b373198faccade6de323a372ed4f9b26bdceefb2ce886df953eebe464b8f')
  20
  21 pkgver() {
  22   cd $_pkgname
  23   git describe --tags | sed 's/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd $_pkgname
  28
  29   # Fix build
  30   sed -i '/post-install.sh/d' meson.build
  31
  32   # Fix AppStream metadata validation
  33   # https://github.com/hbons/SparkleShare/pull/1882
  34   git cherry-pick -n e0c4e972d0b52ef71b0fafe6fb33511e429af955
  35
  36   # Don't use legacy path for AppStream metainfo file
  37   # https://github.com/hbons/SparkleShare/pull/1883
  38   git cherry-pick -n e6775a462a8c56926c9364ae4e4fe2bdbfc08798
  39
  40   # Add X-AppStream-Ignore property to autostart file
  41   # https://github.com/hbons/SparkleShare/pull/1884
  42   echo 'X-AppStream-Ignore=true' >>SparkleShare/Linux/SparkleShare.Autostart.desktop
  43
  44   # Use gtk status icon by default
  45   patch -Np1 -i ../0001-Use-gtk-status-icon-by-default.patch
  46 }
  47
  48 build() {
  49   arch-meson $_pkgname build
  50   ninja -C build
  51 }
  52
  53 package() {
  54   meson install -C build --destdir "$pkgdir"
  55 }