spice-up/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: NicoHood <archlinux {cat} nicohood {dog} de>
   3 # Contributor: btd1337
   4
   5 pkgname=spice-up
   6 pkgver=1.9.1
   7 pkgrel=1
   8 pkgdesc='Create simple and beautiful presentations'
   9 arch=('x86_64')
  10 url='https://github.com/Philip-Scott/Spice-up'
  11 license=('GPL3')
  12 depends=('granite' 'libevdev' 'libgudev' 'libsoup')
  13 makedepends=('meson' 'vala')
  14 checkdepends=('xorg-server-xvfb')
  15 source=("https://github.com/Philip-Scott/Spice-up/archive/$pkgver/Spice-up-$pkgver.tar.gz"
  16         '0001-Add-missing-icons.patch')
  17 sha256sums=('39ca3f5cbfc1dbd46bc0847c81f8f0e41326dbecb8d74d7eb107c5f970a4ef3d'
  18             '77a136fe90b825430eeb7e9d4d3b54eec1b331760d153ea709f4f57d9e8d56b8')
  19
  20 prepare() {
  21   patch -d Spice-up-$pkgver -Np1 -i ../0001-Add-missing-icons.patch
  22 }
  23
  24 build() {
  25   meson build Spice-up-$pkgver \
  26     --prefix=/usr
  27   meson compile -C build
  28 }
  29
  30 check() {
  31 # https://github.com/Philip-Scott/Spice-up/issues/327
  32   dbus-run-session xvfb-run -s '-screen 0 1920x1080x24 -nolisten local' \
  33     meson test -C build || /bin/true
  34 }
  35
  36 package() {
  37   meson install -C build --destdir="$pkgdir"
  38   ln -s com.github.philip-scott.spice-up "$pkgdir/usr/bin/$pkgname"
  39 }