sratom/repos/community-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Ray Rashif <schiv@archlinux.org>
   3 # Contributor: speps <speps at aur dot archlinux dot org>
   4
   5 pkgbase=sratom
   6 pkgname=(sratom sratom-docs)
   7 pkgver=0.6.14
   8 pkgrel=1
   9 pkgdesc="An LV2 Atom RDF serialisation library"
  10 arch=(x86_64)
  11 url="https://drobilla.net/software/sratom.html"
  12 license=(ISC)
  13 makedepends=(doxygen lv2 meson python-sphinx python-sphinx-lv2-theme serd sord)
  14 options=(debug)
  15 source=(https://download.drobilla.net/$pkgname-$pkgver.tar.xz{,.sig})
  16 sha512sums=('3647ccca3ac98299a0bcc30d540788c627445c9a55f0b68a53e08ee45b15138c7a5466c92d1c10eac614325718d4f59eff6f0664f99891e8349e613be675c87d'
  17             'SKIP')
  18 b2sums=('6f468e9a0de97cf83a4f3faeb8ceff8a5502da7f0dff6b5721ef985df352057cda0dbbf13656471ef7f3103a891570e3462ed6bf4517dbc546d9f83115db433b'
  19         'SKIP')
  20 validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard <d@drobilla.net>
  21
  22 _pick() {
  23   local p="$1" f d; shift
  24   for f; do
  25     d="$srcdir/$p/${f#$pkgdir/}"
  26     mkdir -p "$(dirname "$d")"
  27     mv "$f" "$d"
  28     rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  29   done
  30 }
  31
  32 build() {
  33   arch-meson $pkgname-$pkgver build
  34   meson compile -C build
  35 }
  36
  37 check() {
  38   meson test -C build
  39 }
  40
  41
  42 package_sratom() {
  43   depends=(glibc libserd-0.so libsord-0.so lv2)
  44   provides=(libsratom-0.so)
  45   optdepends=('sratom-docs: for developer documentation')
  46
  47   meson install -C build --destdir "$pkgdir"
  48   (
  49     cd "$pkgdir"
  50     _pick $pkgname-docs usr/share/doc
  51   )
  52   install -vDm 644 $pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
  53   install -vDm 644 $pkgname-$pkgver/{NEWS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
  54 }
  55
  56 package_sratom-docs() {
  57   pkgdesc+=" - documentation"
  58
  59   mv -v $pkgname/* "$pkgdir"
  60   mv -v "$pkgdir/usr/share/doc/"sratom{-0,}
  61 }