ssh-tools/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: Sven Wick <sven.wick@gmx.de>
   3
   4 pkgname=ssh-tools
   5 pkgver=1.7
   6 pkgrel=2
   7 pkgdesc="A collection of tools making SSH more convenient"
   8 arch=('any')
   9 url="https://github.com/vaporup/ssh-tools"
  10 license=('GPL')
  11 depends=('openssh')
  12 optdepends=('colordiff: colors for ssh-diff')
  13 makedepends=('git' 'help2man')
  14 _commit='fbf979f8a4f002a94ec2f487885aeebec49f80cb'
  15 source=("$pkgname::git+$url.git#commit=$_commit")
  16 b2sums=('SKIP')
  17
  18 pkgver() {
  19   cd "$pkgname"
  20
  21   git describe --tags | sed 's/^v//'
  22 }
  23
  24 prepare() {
  25   cd "$pkgname"
  26
  27   mkdir man
  28 }
  29
  30 build() {
  31   cd "$pkgname"
  32
  33   # dict with command:description pairings
  34   declare -A pages
  35   pages["ssh-ping"]="check if host is reachable using ssh_config"
  36   pages["ssh-version"]="shows version of the ssh server you are connecting to"
  37   pages["ssh-diff"]="diff a file over ssh"
  38   pages["ssh-facts"]="get some facts about the remote system"
  39   pages["ssh-hostkeys"]="prints server host keys in several formats"
  40   pages["ssh-keyinfo"]="prints keys in several formats"
  41   pages["ssh-certinfo"]="shows validity and information of ssh certificates"
  42   pages["ssh-force-password"]="enforces password authentication"
  43
  44   # generate man pages
  45   for page in "${!pages[@]}"; do
  46     help2man \
  47       --name "${pages[${page}]}" \
  48       --source "${pkgname^^}" \
  49       --no-info \
  50       --version-string "$pkgver" \
  51       --output "man/${page}.1" \
  52      "./${page}"
  53   done
  54 }
  55
  56 package() {
  57   cd "$pkgname"
  58
  59   # scripts
  60   install -vDm755 -t "$pkgdir/usr/bin" ssh-*
  61
  62   # man pages
  63   install -vDm644 -t "$pkgdir/usr/share/man/man1" man/*
  64
  65   # documentation
  66   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
  67 }