stumpwm-contrib/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=stumpwm-contrib
   4 pkgver=r515.g4613a95
   5 pkgrel=2
   6 pkgdesc='Collection of StumpWM modules'
   7 arch=('any')
   8 url='https://github.com/stumpwm/stumpwm-contrib'
   9 license=('GPL2')
  10 depends=('stumpwm')
  11 makedepends=('git')
  12 optdepends=(
  13   'xorg-xprop: for stumpish, the StumpWM Interactive Shell'
  14   'rlwrap: command completion and history in stumpish'
  15   'alsa-utils: manipulate the volume using amixer'
  16   'mpd: display information about mpd'
  17   'surfraw: surf the internet'
  18   'pass: pass integration'
  19   'pinentry: gnupg agent integration'
  20 )
  21 _commit='4613a956add7a17986a3b26c341229466cd13f1d'
  22 source=("$pkgname::git+$url#commit=$_commit")
  23 b2sums=('SKIP')
  24
  25 pkgver() {
  26   cd "$pkgname"
  27
  28   printf 'r%s.g%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  29 }
  30
  31 package() {
  32   cd "$pkgname"
  33
  34   install -vd "$pkgdir/usr/share/stumpwm/contrib"
  35
  36   # skip useless directories/files
  37   find . \
  38     -maxdepth 1 \
  39     -mindepth 1 \
  40     -type d \
  41     -not -path './docs' \
  42     -not -path './.git' \
  43     -exec cp -ra {} "$pkgdir/usr/share/stumpwm/contrib" \;
  44
  45   # documentation
  46   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.org
  47 }