sysstat/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
   2 # Contributor: Martin Devera <devik@cdi.cz>
   3
   4 pkgname=sysstat
   5 pkgver=12.7.2
   6 pkgrel=1
   7 pkgdesc="a collection of performance monitoring tools (iostat,isag,mpstat,pidstat,sadf,sar)"
   8 arch=('x86_64')
   9 url="http://pagesperso-orange.fr/sebastien.godard/"
  10 license=('GPL')
  11 depends=('lm_sensors')
  12 makedepends=('systemd')
  13 optdepends=('tk: to use isag'
  14             'gnuplot: to use isag')
  15 options=('zipman')
  16 backup=('etc/conf.d/sysstat'
  17         'etc/conf.d/sysstat.ioconf')
  18 source=("https://github.com/sysstat/sysstat/archive/refs/tags/v${pkgver}.tar.gz"
  19         'lib64-fix.patch')
  20 sha512sums=('c9dbde263122c4adc0d22769a1ba69c9011bc8264a9298c0c2fcd3262a785e9cef34b69bb84ddc2bafbf11de5f2110946bbe7e88a98f03f99524894a5c02e0de'
  21             '6caae9962a636e5152b0462d0dce835d8f658848723bee2d7ac903a0f170a491882c819457c882bcee41159960fa243fb843a2389c9a4ceeea061a5520e01103')
  22
  23 prepare() {
  24   cd "${srcdir}"/"${pkgname}"-"${pkgver}"
  25   patch -p1 < "${srcdir}/lib64-fix.patch"
  26   autoreconf
  27 }
  28
  29 build() {
  30   cd "${srcdir}"/"${pkgname}"-"${pkgver}"
  31   conf_dir=/etc/conf.d ./configure --prefix=/usr \
  32         --mandir=/usr/share/man \
  33         --enable-install-cron \
  34         --enable-copy-only \
  35   --disable-compress-manpg
  36   # patch makefile for FULL RELRO builds
  37   sed -e 's|CFLAGS = |CFLAGS += \$(CPPFLAGS) |' -e 's|LFLAGS = |LFLAGS = $(LDFLAGS) |' -i Makefile
  38   make
  39 }
  40
  41 package() {
  42   cd "${srcdir}"/"${pkgname}"-"${pkgver}"
  43   mkdir -p "${pkgdir}"/usr/lib/systemd/system
  44   make DESTDIR="${pkgdir}" install
  45   chown -R root:root "${pkgdir}"
  46   rm -rf "${pkgdir}"/etc/rc*
  47 }