taskwarrior-tui/trunk/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2
   3 pkgname=taskwarrior-tui
   4 pkgver=0.23.7
   5 pkgrel=2
   6 pkgdesc="A terminal user interface for taskwarrior"
   7 arch=('x86_64')
   8 url="https://github.com/kdheepak/taskwarrior-tui"
   9 license=('MIT')
  10 depends=('task')
  11 makedepends=('cargo' 'git')
  12 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz"
  13         "git+https://github.com/kdheepak/taskwarrior-testdata")
  14 sha256sums=('9e7dbd61219a0a7cc1916c71d05b778e515fb4eff5a22c523e4efb3ff826f4cb'
  15             'SKIP')
  16
  17 prepare() {
  18   cd "$pkgname-$pkgver"
  19   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  20 }
  21
  22 build() {
  23   cd "$pkgname-$pkgver"
  24   cargo build --release --frozen --all-features
  25 }
  26
  27 # check() {
  28 #   cd "$pkgname-$pkgver"
  29 #   export TASKRC="../taskwarrior-testdata/.taskrc"
  30 #   export TASKDATA="../taskwarrior-testdata/.task"
  31 #   cargo test --frozen --all-features
  32 # }
  33
  34 package() {
  35   cd "$pkgname-$pkgver"
  36   install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  37   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  38   install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  39   install -Dm 644 "docs/$pkgname.1" -t "$pkgdir/usr/share/man/man1"
  40   install -Dm 644 "completions/$pkgname.bash" "${pkgdir}/usr/share/bash-completion/completions/$pkgname"
  41   install -Dm 644 "completions/$pkgname.fish" -t "${pkgdir}/usr/share/fish/vendor_completions.d"
  42   install -Dm 644 "completions/_$pkgname" -t "${pkgdir}/usr/share/zsh/site-functions"
  43 }
  44
  45 # vim: ts=2 sw=2 et: