tcpreplay/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Timothy Redaelli <timothy.redaelli@gmail.com>
   3 # Contributor: Sébastien Duquette <ekse.0x@gmail.com>
   4 # Contributor: Dawid Wrobel <cromo@klej.net>
   5
   6 pkgname=tcpreplay
   7 pkgver=4.4.3
   8 pkgrel=1
   9 pkgdesc='Gives the ability to replay previously captured traffic in a libpcap format'
  10 url='https://tcpreplay.appneta.com'
  11 arch=('x86_64')
  12 license=('GPL3')
  13 depends=('libpcap' 'libdnet' 'autogen')
  14 makedepends=('tcpdump')
  15 optdepends=('tcpdump: decoding of packets support')
  16 options=('!emptydirs')
  17 source=(https://github.com/appneta/tcpreplay/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz{,.asc})
  18 sha512sums=('f69137ef41d16f4acda4190245f73f0b3db950783e5a6fc3374c27eae80c8bf096f5392c18c1b33b90bc32380625c5b5f149f7ec1c50b971ddd761279abffe68'
  19             'SKIP')
  20 b2sums=('4aebf1ae6f43a0fa51a9a0bb7220a23de0115748e0c659b207dfc2d438b371829edf9f34f4de9b8d4aafa64acc1b4ddf93d07327b4fed0785caa9deac141ceaa'
  21         'SKIP')
  22 validpgpkeys=('84E4FA215C934A7D97DC76D5E9E2149793BDE17E') # Fred Klassen <tcpreplay@appneta.com>
  23
  24 prepare() {
  25   cd ${pkgname}-${pkgver}
  26   autoreconf -fiv
  27 }
  28
  29 build() {
  30   cd ${pkgname}-${pkgver}
  31   ./configure \
  32     --prefix=/usr \
  33     --disable-local-libopts \
  34     --enable-dynamic-link \
  35     --enable-shared \
  36     --with-libdnet \
  37     --with-tcpdump=/usr/bin/tcpdump \
  38     ac_cv_header_net_bpf_h=n
  39   make
  40 }
  41
  42 check() {
  43   cd ${pkgname}-${pkgver}
  44   make -j1 -C test tcpprep
  45 }
  46
  47 package() {
  48   cd ${pkgname}-${pkgver}
  49   make DESTDIR="${pkgdir}" install
  50 }
  51
  52 # vim: ts=2 sw=2 et: