teamspeak3-server/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: nyyu <mail@nyyu.tk>
   3 # Contributor: Malte Rabenseifner <mail@malte-rabenseifner.de>
   4 # Contributor: EnteEnteEnte <ducksource@duckpond.ch>
   5
   6 pkgname=teamspeak3-server
   7 pkgver=3.13.7
   8 pkgrel=1
   9 pkgdesc='TeamSpeak is software for quality voice communication via the Internet (server)'
  10 url='https://www.teamspeak.com/en/'
  11 arch=('x86_64')
  12 license=('custom')
  13 depends=('glibc' 'gcc-libs')
  14 optdepends=(
  15   'mariadb-connector-c: MariaDB backend'
  16   'postgresql-libs: PostgreSQL backend'
  17 )
  18 backup=(etc/teamspeak3-server.ini
  19         etc/tsdns_settings.ini)
  20 install=teamspeak3-server.install
  21 source=(teamspeak3-server.ini
  22         teamspeak3-server.service
  23         PERMISSION.eml)
  24 source_i686=(https://files.teamspeak-services.com/releases/server/${pkgver}/teamspeak3-server_linux_x86-${pkgver}.tar.bz2)
  25 source_x86_64=(https://files.teamspeak-services.com/releases/server/${pkgver}/teamspeak3-server_linux_amd64-${pkgver}.tar.bz2)
  26 sha256sums=('a5ec72d7b8b199e37fc2277d68ef470a6a441e1f964c77f46f0c82d4b586ce6d'
  27             '73c38a5e70caf042a5997ae831e33be7ba83e5c31ccca01c257c929569149acd'
  28             '98e3331a803ce0ff85500a3908a61fe105d47ea3c31affc2f605d8385315ca5b')
  29 sha256sums_x86_64=('775a5731a9809801e4c8f9066cd9bc562a1b368553139c1249f2a0740d50041e')
  30
  31 if [ "${CARCH}" == "x86_64" ]; then
  32   _TSARCH='amd64'
  33 elif [ "${CARCH}" == "i686" ]; then
  34   _TSARCH='x86'
  35 fi
  36
  37 package() {
  38   install -Dm 644 teamspeak3-server.ini -t "${pkgdir}/etc"
  39   install -Dm 644 teamspeak3-server_linux_${_TSARCH}/tsdns/tsdns_settings.ini.sample "${pkgdir}/etc/tsdns_settings.ini"
  40   install -Dm 644 teamspeak3-server.service -t "${pkgdir}/usr/lib/systemd/system"
  41
  42   install -Dm 755 teamspeak3-server_linux_${_TSARCH}/ts3server -t "${pkgdir}/usr/bin"
  43   install -Dm 755 teamspeak3-server_linux_${_TSARCH}/tsdns/tsdnsserver -t "${pkgdir}/usr/bin"
  44   install -Dm 644 teamspeak3-server_linux_${_TSARCH}/*.so -t "${pkgdir}/usr/lib"
  45   install -Dm 644 teamspeak3-server_linux_${_TSARCH}/LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  46
  47   install -d "${pkgdir}/usr/share/doc/teamspeak3-server" \
  48     "${pkgdir}/usr/share/teamspeak3-server"
  49
  50   cp -a teamspeak3-server_linux_${_TSARCH}/doc "${pkgdir}/usr/share/doc/teamspeak3-server"
  51   cp -a teamspeak3-server_linux_${_TSARCH}/serverquerydocs "${pkgdir}/usr/share/doc/teamspeak3-server"
  52   cp -a teamspeak3-server_linux_${_TSARCH}/sql "${pkgdir}/usr/share/teamspeak3-server"
  53
  54   find "${pkgdir}/usr/share/teamspeak3-server" -type d -exec chmod 755 {} \;
  55   find "${pkgdir}/usr/share/teamspeak3-server" -type f -exec chmod 644 {} \;
  56   find "${pkgdir}/usr/share/doc/teamspeak3-server" -type d -exec chmod 755 {} \;
  57   find "${pkgdir}/usr/share/doc/teamspeak3-server" -type f -exec chmod 644 {} \;
  58 }
  59
  60 # vim: ts=2 sw=2 et: