testssl.sh/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Johannes Schleifenbaum <johannes [at] js-webcoding [dot] de>
   3
   4 pkgname=testssl.sh
   5 _pkgver=3.0.8
   6 pkgver=${_pkgver/-/.}
   7 pkgrel=2
   8 pkgdesc='Testing TLS/SSL encryption'
   9 url='https://github.com/drwetter/testssl.sh'
  10 arch=('any')
  11 license=('GPL2')
  12 depends=('bash' 'coreutils' 'util-linux' 'openssl' 'bind-tools' 'procps-ng')
  13 makedepends=('perl' 'perl-data-dump' 'perl-json' 'perl-test-base')
  14 source=(https://github.com/drwetter/testssl.sh/archive/v${_pkgver}/${pkgname}-${pkgver}.tar.gz
  15         set-install-dir.patch)
  16 sha512sums=('4634bc5dc57ad8910ca097b22d86511a26e855fb4dc7bef9550a795cb1f53a959b8472008756b40a670d7433ad56236b5a36fe0c88c15de99fdf586e9919b080'
  17             '82bb83a5553bdc8d02cb655c76163ac9c86b0fc1cff9c5627cb035eae016c5a8b76a3a9e278de4578779bf63a35548815a53911288872530d65c1100c065f621')
  18 b2sums=('cf463236fb0812c2bc5fd5673d0d2d395fc405697817827ee8c660c96d789601a090b57febd48400e33fd9f28b23d42d432734b176b23a8e8ddf710c9b275485'
  19         '26f90e385085e0c50bd877b37e85f489177bcef0be90baad096c6f3e95732542e2adcaf2aa03ba75d264607d869ea479b768834ba476e258eea291c452f4f3b9')
  20
  21 prepare() {
  22   cd ${pkgname}-${_pkgver}
  23   patch -p0 < "${srcdir}/set-install-dir.patch"
  24   rm bin/openssl.Linux*
  25 }
  26
  27 check() {
  28   cd ${pkgname}-${_pkgver}
  29   # the bundled openssl segfaults in the tests
  30   # TESTSSL_INSTALL_DIR="$(pwd)" prove -v
  31 }
  32
  33 package() {
  34   cd ${pkgname}-${_pkgver}
  35   install -Dm 755 testssl.sh "${pkgdir}/usr/bin/testssl"
  36   install -Dm 644 etc/* -t "${pkgdir}/usr/share/testssl.sh/etc"
  37   install -Dm 644 Readme.md doc/testssl.1.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  38   install -Dm 644 doc/testssl.1 -t "${pkgdir}/usr/share/man/man1"
  39 }
  40
  41 # vim: ts=2 sw=2 et: