tpm2-totp/trunk/PKGBUILD

   1 # Maintainer: Jonas Witschel <diabonas@archlinux.org>
   2 pkgname=tpm2-totp
   3 pkgver=0.3.0
   4 pkgrel=1
   5 pkgdesc='Attest the trustworthiness of a device against a human using time-based one-time passwords'
   6 arch=('x86_64')
   7 url='https://github.com/tpm2-software/tpm2-totp'
   8 license=('BSD')
   9 depends=('qrencode' 'tpm2-tss' 'libtss2-esys.so' 'libtss2-mu.so' 'libtss2-tctildr.so')
  10 checkdepends=('iproute2' 'oath-toolkit' 'swtpm' 'tpm2-tools')
  11 optdepends=('initramfs: dracut and mkinitcpio hooks to display the TOTP during boot')
  12 source=("$url/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz"{,.asc})
  13 sha512sums=('d47cc8155a60a464afe602c3114ff8e6b2ff825457e6069693947421716b97c34b00f70adbcb4cda1b5b9639b8a3dfc7800295bbff99822da7a8077ebf78d6b2'
  14             'SKIP')
  15 validpgpkeys=('D6B4D8BAC7E0CC97DCD4AC7272E88B53F7A95D84'  # Andreas Fuchs <andreas.fuchs@sit.fraunhofer.de>
  16               'FE2E6249201CA54A4FB90D066E80CA1446879D04') # Jonas Witschel <diabonas@gmx.de>
  17
  18 build() {
  19         cd "$pkgname-$pkgver"
  20         ./configure --prefix=/usr \
  21                     --libexecdir=/usr/lib \
  22                     --with-dracutmodulesdir=/usr/lib/dracut/modules.d \
  23                     --with-mkinitcpiodir=/usr/lib/initcpio \
  24                     $( ((CHECKFUNC)) && echo --enable-integration)
  25         make
  26 }
  27
  28 check() {
  29         cd "$pkgname-$pkgver"
  30         make check
  31 }
  32
  33 package() {
  34         cd "$pkgname-$pkgver"
  35         make DESTDIR="$pkgdir" install
  36         install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  37 }