ttf-dejavu/trunk/PKGBUILD

   1 # Maintainer: Jan de Groot <jgc@archlinux.org>
   2 # Contributor: Michal Krenek <mikos@sg1.cz>
   3
   4 pkgname=ttf-dejavu
   5 pkgver=2.37+18+g9b5d1b2f
   6 pkgrel=3
   7 pkgdesc="Font family based on the Bitstream Vera Fonts with a wider range of characters"
   8 arch=('any')
   9 url="https://dejavu-fonts.github.io/"
  10 license=('custom')
  11 makedepends=('git' 'fontforge' 'perl-font-ttf')
  12 provides=('ttf-font')
  13 _commit=9b5d1b2ffeec20c7b46aa89c0223d783c02762cf  # master
  14 source=("git+https://github.com/dejavu-fonts/dejavu-fonts.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd dejavu-fonts
  19   git describe --tags | sed 's/^version_//;s/_/./;s/-/+/g'
  20 }
  21
  22 build() {
  23   cd dejavu-fonts
  24   make full-ttf
  25 }
  26
  27 package() {
  28   cd dejavu-fonts
  29   install -Dt "$pkgdir/usr/share/fonts/TTF" -m644 build/*.ttf
  30   install -Dt "$pkgdir/usr/share/fontconfig/conf.avail" -m644 fontconfig/*.conf
  31
  32   mkdir "$pkgdir/usr/share/fontconfig/conf.default"
  33   ln -srt "$pkgdir/usr/share/fontconfig/conf.default" \
  34     "$pkgdir"/usr/share/fontconfig/conf.avail/*
  35
  36   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE
  37 }