uasm/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: Oleksandr Natalenko <oleksandr@natalenko.name>
   3 # Contributor: Darren Ng <$(base64 --decode <<<VW4xR2ZuQGdtYWlsLmNvbQo=)>
   4 # Contributor: Dan Bryant <$(base64 --decode <<<VanVzdGRhbjk2QGdtYWlsLmNvbQo=)>
   5
   6 pkgname=uasm
   7 pkgver=2.56.2
   8 pkgrel=1
   9 pkgdesc='A MASM-compatible assembler'
  10 arch=('x86_64')
  11 url='http://www.terraspace.co.uk/uasm.html'
  12 # Previous versions were licensed under the following licenses:
  13 # - JWasm License
  14 # - Sybase Open Watcom Public License 1.0
  15 # Of which both are the same license with the following SPDX
  16 # identifier: Watcom-1.0.
  17 # The uasm-nocolor script uses code from stackoverflow, which
  18 # is licensed under CC-BY-SA-3.0.
  19 license=(
  20   'custom:Watcom-1.0'
  21   'custom:CC-BY-SA-3.0'
  22 )
  23 makedepends=('git')
  24 optdepends=('sed: for uasm-nocolor')
  25 _commit='4dc0a4f96e2296c2e56c9224a2a0453c99470e2c'
  26 source=(
  27   "$pkgname::git+https://github.com/Terraspace/UASM#commit=$_commit"
  28   'uasm_extended_guide_v2.52.pdf::http://www.terraspace.co.uk/uasm252_ext.pdf'
  29   'uasm-nocolor'
  30 )
  31 sha512sums=('SKIP'
  32             '8848dc5f174c4c533a9b4dbd84da86fc8c8d0e67afa5648a016228c739a8e0e359c6ae897618ebab50b5b1ca64b879f037bfb6406c6fe84fb28eb59678989cb2'
  33             '6099e122db071419e2158f37611726d6e2d9a73a0a6966320c8b7cd0621730df52078eaec70ab03358a40aece7b3312072370ba864cfd7f00f92c791ef98f0ca')
  34 b2sums=('SKIP'
  35         '37b1cbee60d79dd6bd9fd66b9a4c25a25d2dc52a582c6dd5d1087b48f5f507bda667a5687d3774ae57f9bc289553d52573886d1e48cd2c5098e57bab79074477'
  36         '29f03fede4f03363b106afe2a502c45b3ef8dcf5ae681f5e0f495908c83309f34b9f6fc663976814f03d3a73e4ca62762963caaa4c96a6c36b0c4ad806b1e1db')
  37
  38 pkgver() {
  39   cd "$pkgname"
  40
  41   git describe --tags | sed 's/^v//'
  42 }
  43
  44 build() {
  45   cd "$pkgname"
  46
  47   # fix FTBFS
  48   # https://gcc.gnu.org/gcc-10/porting_to.html#common
  49   make CC="gcc -fcommon" -f gccLinux64.mak
  50 }
  51
  52 package() {
  53   cd "$pkgname"
  54
  55   # binary
  56   install -vDm755 -t "$pkgdir/usr/bin" GccUnixR/uasm "$srcdir/uasm-nocolor"
  57
  58   # documentation
  59   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" \
  60     {Readme,History}.txt \
  61     README.md \
  62     Doc/* \
  63     "$srcdir/uasm_extended_guide_v2.52.pdf"
  64
  65   # license
  66   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" License.txt
  67 }