vigra/trunk/PKGBUILD

   1 # Maintainer: Bruno Pagani <archange@archlinux.org>
   2 # Contributor: AndyRTR <andyrtr@archlinux.org>
   3 # Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
   4
   5 pkgname=vigra
   6 pkgver=1.11.1.r67+g093d57d1
   7 pkgrel=9
   8 pkgdesc="Computer vision library"
   9 arch=(x86_64)
  10 url="https://ukoethe.github.io/vigra/"
  11 license=(custom:MIT)
  12 depends=(libpng libtiff openexr gcc-libs sh hdf5 fftw)
  13 makedepends=(git cmake boost python-numpy)
  14 checkdepends=(python-nose)
  15 optdepends=('python: for python bindings'
  16             'boost-libs: for python bindings')
  17 source=(git+https://github.com/ukoethe/vigra#commit=093d57d15c8c237adf1704d96daa6393158ce299
  18         vigra-python3.10.patch::https://github.com/ukoethe/vigra/commit/e7e656c29083729090dd3fb3ec214a888e0b3e8d.patch
  19         vigra-numpy1.20.patch::https://github.com/ukoethe/vigra/commit/23ad778502c6436fb6e40ade5e9fd9ddbbad9f35.patch
  20         vigra-bind-c17.patch::https://github.com/ukoethe/vigra/pull/500.patch
  21         vigra-openexr3.patch)
  22 sha256sums=('SKIP'
  23             '18ab55f011458963785442947ed07dd44cb93e8879a8bdda495fb330011621a4'
  24             '014cff1a7e69415ec15cef6635a7279c429d5bf8df861a4d89193d2209de604d'
  25             '9c2289f75e6444ad3316b0d46dd7276de10ae81d194cfa10ed84d1e5236aaea0'
  26             '2572717e39f916c7c463b8f49306b683c5923906be2721f7da181c58b3a2b34b')
  27
  28 pkgver() {
  29   cd ${pkgname}
  30   git describe --tags --match "Version-*" | sed 's/^Version-//;s/\([^-]*-g\)/r\1/;s/-/./g;s/\.g/+g/'
  31 }
  32
  33 prepare() {
  34   cd ${pkgbase}
  35   patch -p1 < ../vigra-openexr3.patch
  36   patch -p1 < ../vigra-python3.10.patch
  37   patch -p1 < ../vigra-numpy1.20.patch
  38   # https://github.com/ukoethe/vigra/issues/504
  39   patch -R -p1 < ../vigra-bind-c17.patch
  40 }
  41
  42 build() {
  43   cmake -B build -S ${pkgbase} \
  44     -DCMAKE_INSTALL_PREFIX=/usr \
  45     -DPYTHON_EXECUTABLE=/usr/bin/python \
  46     -DDOCINSTALL=share/doc \
  47     -DWITH_OPENEXR=true \
  48     -DWITH_VIGRANUMPY=1
  49     #-DBUILD_DOCS=OFF \
  50   make -C build
  51 }
  52
  53 check() {
  54   # https://github.com/ukoethe/vigra/issues/491
  55   make -C build -j1 -k check || echo "Tests failed"
  56 }
  57
  58 package() {
  59   make -C build DESTDIR="${pkgdir}" install
  60   install -Dm644 ${pkgbase}/LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
  61 }