viu/trunk/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2 # Contributor: Wesley Moore <wes@wezm.net>
   3
   4 pkgname=viu
   5 pkgver=1.4.0
   6 pkgrel=2
   7 pkgdesc="Simple terminal image viewer"
   8 arch=('x86_64')
   9 url="https://github.com/atanunq/viu"
  10 license=('MIT')
  11 depends=('gcc-libs' 'libsixel')
  12 makedepends=('cargo')
  13 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
  14 sha256sums=('9b359c2c7e78d418266654e4c94988b0495ddea62391fcf51512038dd3109146')
  15 options=('!lto')
  16
  17 prepare() {
  18   cd "$pkgname-$pkgver"
  19   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  20 }
  21
  22 build() {
  23   cd "$pkgname-$pkgver"
  24   cargo build --frozen --release --features sixel
  25 }
  26
  27 check() {
  28   cd "$pkgname-$pkgver"
  29   cargo test --frozen
  30 }
  31
  32 package() {
  33   cd "$pkgname-$pkgver"
  34   install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  35   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  36   install -Dm 644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
  37 }
  38
  39 # vim: ts=2 sw=2 et: