xcb-imdkit/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: csslayer <wengxt AT gmail com>
   3
   4 pkgname=xcb-imdkit
   5 pkgver=1.0.5
   6 pkgrel=1
   7 pkgdesc="Input method development support for xcb"
   8 arch=('x86_64')
   9 url="https://github.com/fcitx/xcb-imdkit"
  10 license=('GPL')
  11 depends=('xcb-util' 'xcb-util-keysyms')
  12 makedepends=('extra-cmake-modules' 'ninja' 'uthash' 'xorgproto')
  13 source=("https://download.fcitx-im.org/fcitx5/xcb-imdkit/xcb-imdkit-$pkgver.tar.xz"{,.sig})
  14 sha512sums=('b021015e819c1d1722e5a04050a6839c28c38912c571cbe7a90c7e9055c36b77c3d16ee0930c86d4b602f2f3a2ad7c087d80101ff20a67255c45c0433358dd31'
  15             'SKIP')
  16 validpgpkeys=('2CC8A0609AD2A479C65B6D5C8E8B898CBF2412F9') # Weng Xuetian <wengxt@gmail.com>
  17
  18 build() {
  19   cd $pkgname-$pkgver
  20
  21   cmake -GNinja -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_INSTALL_LIBDIR=/usr/lib .
  22   ninja
  23 }
  24
  25 check() {
  26   cd $pkgname-$pkgver
  27   ninja test
  28 }
  29
  30 package() {
  31   cd $pkgname-$pkgver
  32   DESTDIR="$pkgdir" ninja install
  33 }