zita-mu1/repos/community-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dave@sleepmap.de>
   2 pkgname=zita-mu1
   3 pkgver=0.3.3
   4 pkgrel=3
   5 pkgdesc="A simple JACK app used to organise stereo monitoring"
   6 arch=('x86_64')
   7 url="https://kokkinizita.linuxaudio.org/linuxaudio/zita-mu1-doc/quickguide.html"
   8 license=('GPL3')
   9 groups=('pro-audio')
  10 depends=('cairo' 'clxclient' 'clthreads' 'jack')
  11 makedepends=('gendesk')
  12 source=("https://kokkinizita.linuxaudio.org/linuxaudio/downloads/${pkgname}-${pkgver}.tar.bz2")
  13 sha512sums=('1e01a92840e12854ffeb33e713a6257bc60ce140f0e7786a06dee73bd2cd8ce7f4904327ea107456a4c64eb8bf636a863ff12d0505512d21471ff08eb9d3f12c')
  14
  15 prepare() {
  16   cd "${pkgname}-${pkgver}"
  17   # remove optimization
  18   # fix binary install
  19   sed -e '/native/d' \
  20       -i source/Makefile
  21   # XDG desktop file
  22   gendesk -n \
  23           --pkgname ${pkgname} \
  24           --pkgdesc "${pkgdesc}" \
  25           --name zita-mu1 \
  26           --categories "AudioVideo;Audio"
  27 }
  28
  29 build() {
  30   cd "${pkgname}-${pkgver}/source"
  31   make PREFIX=/usr
  32 }
  33
  34 package() {
  35   cd "${pkgname}-${pkgver}/source"
  36   make PREFIX=/usr DESTDIR="$pkgdir" install
  37   # docs
  38   install -t "${pkgdir}/usr/share/doc/${pkgname}" \
  39     -vDm644 ../{AUTHORS,README}
  40   # XDG desktop integration
  41   install -vDm 644 "../${pkgname}.desktop" \
  42     -t "${pkgdir}/usr/share/applications/"
  43   # html
  44   install -t "${pkgdir}/usr/share/doc/${pkgname}/html" \
  45     -vDm644 ../doc/html/*
  46 }
  47 # vim:set ts=2 sw=2 et: