alicloud-vault/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   3 # Contributor: Andreas 'Segaja' Schleifer <archlinux at segaja dot de>
   4
   5 pkgname=alicloud-vault
   6 pkgver=1.3.4
   7 pkgrel=2
   8 pkgdesc='Vault for securely storing and accessing Alibaba Cloud credentials in development environments'
   9 url='https://github.com/arafato/alicloud-vault'
  10 arch=('x86_64')
  11 license=('MIT')
  12 depends=('glibc')
  13 makedepends=('go')
  14 source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  15 sha512sums=('d2a052c981f6c7322c323ad8b7313aa4da5f1b99b4391ce9ae1e8c1f93cb11ba86a3a0ab14cb9564d11c2a810252a986e1d32fdba8adf1438e71cfc85e05b13a')
  16 b2sums=('04bebc0507565494832e507c02a7d04af0052d23997dae94f2dee636841b4bdd414726b7799e7ebc125e74857bb84fd24a68b087e539999a4aaebe32f13a51e3')
  17
  18 build() {
  19   cd ${pkgname}-${pkgver}
  20   export GO11MODULE=on
  21   export CGO_LDFLAGS="${LDFLAGS}"
  22   export CGO_CPPFLAGS="${CPPFLAGS}"
  23   export CGO_CFLAGS="${CFLAGS}"
  24   export CGO_CXXFLAGS="${CXXFLAGS}"
  25   export GOFLAGS="-buildmode=pie -trimpath"
  26   go build -v \
  27     -ldflags "-linkmode=external -extldflags '${LDFLAGS}' -X main.Version=${pkgver}" .
  28 }
  29
  30 check() {
  31   cd ${pkgname}-${pkgver}
  32   go test ./...
  33 }
  34
  35 package() {
  36   cd ${pkgname}-${pkgver}
  37   install -Dm 755 ${pkgname} -t "${pkgdir}/usr/bin"
  38   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  39   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  40   install -Dm 644 "${pkgname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
  41 }
  42
  43 # vim: ts=2 sw=2 et: