alure/trunk/PKGBUILD

   1 # Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
   2 # Contributor: Markus Martin <markus@archwyrm.net>
   3
   4 pkgname=alure
   5 pkgver=1.2
   6 pkgrel=10
   7 pkgdesc='Utility library to help manage common tasks with OpenAL applications.'
   8 arch=('x86_64')
   9 url='https://kcat.tomasu.net/alure.html'
  10 license=('MIT')
  11 depends=('openal' 'libsndfile' 'libvorbis' 'flac' 'mpg123' 'dumb' 'fluidsynth')
  12 makedepends=('cmake')
  13 source=("https://kcat.tomasu.net/alure-releases/${pkgname}-${pkgver}.tar.bz2"
  14         build.patch
  15         dumb-2.patch)
  16 sha256sums=('465e6adae68927be3a023903764662d64404e40c4c152d160e3a8838b1d70f71'
  17             '21029cfc8900b8270f6c7a79235e09a05d45d0b03b221d9d856a27e98cc0931b'
  18             '379210476980d5e2754b015d5505dff620ed3297a99c08509c757fa88ef46300')
  19
  20 prepare() {
  21   cd $pkgname-$pkgver
  22   patch -p1 -i ../build.patch
  23   patch -p1 -i ../dumb-2.patch # Fix build with dumb 2 (Gentoo)
  24 }
  25
  26 build() {
  27   cmake -B build -S $pkgname-$pkgver \
  28     -DCMAKE_INSTALL_PREFIX=/usr \
  29     -DCMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects" \
  30     -DDYNLOAD=OFF
  31 # Fix build with fluidsynth 2.4
  32   find -name build.make | xargs sed -e 's|\;| |g' -i
  33   cmake --build build
  34 }
  35
  36 package() {
  37   DESTDIR="$pkgdir" cmake --install build
  38
  39   install -Dm0644 $pkgname-$pkgver/COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
  40 }