arch-audit/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Christian Rebischke <Chris.Rebischke@archlinux.org>
   3 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   4
   5 pkgname=arch-audit
   6 pkgver=0.1.20
   7 pkgrel=1
   8 pkgdesc='A utility like pkg-audit based on Arch Security Team data'
   9 url='https://gitlab.com/ilpianista/arch-audit'
  10 depends=('glibc' 'gcc-libs' 'curl' 'libcurl.so' 'libalpm.so')
  11 makedepends=('cargo' 'pkg-config' 'scdoc')
  12 arch=('x86_64')
  13 license=('MIT')
  14 backup=('etc/arch-audit/settings.toml')
  15 source=("https://gitlab.com/ilpianista/arch-audit/-/archive/${pkgver}/arch-audit-${pkgver}.tar.gz")
  16 sha512sums=('e0bdd5adb3c44677d39c8e618c8c8f666f1e2caaead82fc666468c46b296cb4d15584939715995bc6d3d8f996bd3127478bc6008dbdef677fee80063f2bc059e')
  17 b2sums=('02ba56f1b4780da7e006ac25736afb6e0474502cc7d645b2eb48650c6d71878b1de349b9a072f2cd1d013254f68d79786d9195c98c520407e256e6fa9b63f2e4')
  18
  19 build() {
  20   cd "${pkgname}-${pkgver}"
  21   cargo build --release --locked
  22 }
  23
  24 check() {
  25   cd "${pkgname}-${pkgver}"
  26   cargo test --release --locked
  27 }
  28
  29 package() {
  30   cd "${pkgname}-${pkgver}"
  31
  32   make DESTDIR="${pkgdir}" PREFIX=/usr install
  33
  34   install -Dm 644 contrib/hooks/arch-audit.hook -t "${pkgdir}/usr/share/${pkgname}"
  35   install -Dm 644 contrib/config/settings.toml -t "${pkgdir}/etc/arch-audit"
  36
  37   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  38   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  39 }
  40
  41 # vim: ts=2 sw=2 et: