balsa/trunk/PKGBUILD

   1 # Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: Brad Fanella <bradfanella@archlinux.us>
   4 # Contributor: Roman Kyrylych <roman@archlinux.org>
   5
   6 pkgname=balsa
   7 pkgver=2.6.4
   8 pkgrel=1
   9 pkgdesc="An e-mail client for GNOME"
  10 arch=('x86_64')
  11 url='https://pawsa.fedorapeople.org/balsa/'
  12 license=('GPL')
  13 depends=('gmime3' 'webkit2gtk' 'libical' 'libnotify'
  14          'gpgme' 'gtksourceview4' 'gspell')
  15 makedepends=('yelp-tools' 'intltool')
  16 changelog=$pkgname.changelog
  17 source=(https://pawsa.fedorapeople.org/balsa/$pkgname-$pkgver.tar.xz)
  18 sha256sums=('befa5984511db33d41f2b1ecbfc99e22a15d45d08efe5d737b5174a1a6ac8fc1')
  19
  20 build() {
  21   cd "${srcdir}"/$pkgname-$pkgver
  22
  23   ./configure --prefix=/usr \
  24       --sysconfdir=/etc \
  25       --localstatedir=/var \
  26       --with-gss \
  27       --with-ldap \
  28       --with-gtksourceview \
  29       --with-spell-checker=gspell \
  30       --with-rubrica \
  31       --with-sqlite \
  32       --with-gnome \
  33       --with-html-widget=webkit2
  34   make
  35 }
  36
  37 package() {
  38   cd "${srcdir}"/$pkgname-$pkgver
  39
  40   make GTK_UPDATE_ICON_CACHE=/bin/true DESTDIR="${pkgdir}" install
  41 }