bore/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2
   3 pkgname=bore
   4 pkgver=0.5.0
   5 pkgrel=1
   6 pkgdesc="A command line tool for making tunnels to localhost"
   7 arch=('x86_64')
   8 url="https://github.com/ekzhang/bore"
   9 license=('MIT')
  10 depends=('gcc-libs')
  11 makedepends=('cargo')
  12 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
  13 sha512sums=('55d783a46e25393fc003d9c90760c141692af88fe88fecfc27c632bdc6d3352309691f8995484d9a94022c0e8e1636480104d3b7f20bf848647bb34770a8b170')
  14
  15 prepare() {
  16   cd "$pkgname-$pkgver"
  17   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  18 }
  19
  20 build() {
  21   cd "$pkgname-$pkgver"
  22   cargo build --release --frozen
  23 }
  24
  25 check() {
  26   cd "$pkgname-$pkgver"
  27   cargo test --frozen
  28 }
  29
  30 package() {
  31   cd "$pkgname-$pkgver"
  32   install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  33   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  34   install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  35 }
  36
  37 # vim: ts=2 sw=2 et: