camlp5/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Baptiste Jonglez <baptiste--aur at jonglez dot org>
   2 # Contributor: Matej Grabovsky <matej.grabovsky at gmail>
   3 # Contributor: Kohei Suzuki <eagletmt@gmail.com>
   4 # Contributor: Thomas Dziedzic < gostrc at gmail >
   5 # Contributor: Nathan Owe <ndowens.aur at gmail dot com>
   6 # Contributor: George Giorgidze <giorgidze@gmail.com>
   7 # Contributor: Massimiliano Brocchini <brocchini@netseven.it>
   8 # Contributor: Tej Chajed <tchajed at mit dot edu>
   9
  10 pkgname=camlp5
  11 pkgver=8.0
  12 _relname=rel8.00.04
  13 pkgrel=5
  14 arch=('x86_64')
  15 pkgdesc='A preprocessor-pretty-printer of OCaml.'
  16 url='https://camlp5.github.io/'
  17 license=('BSD')
  18 depends=('ocaml' 'camlp-streams')
  19 makedepends=('ocaml-compiler-libs' 'ocaml-findlib')
  20 source=("camlp5-${_relname}.tar.gz::https://github.com/camlp5/camlp5/archive/$_relname.tar.gz")
  21 sha256sums=('bddbcb5c3c2d410c9a61c4dfb6e46e3bbe984d25ac68221a7a65c82a29956b1d')
  22 options=('!strip' 'staticlibs')
  23
  24 build() {
  25   cd "${srcdir}/camlp5-${_relname}"
  26
  27   ./configure \
  28     -prefix '/usr' \
  29     -mandir '/usr/share/man' \
  30     -strict
  31
  32   make world.opt
  33 }
  34
  35 package() {
  36   cd "${srcdir}/camlp5-${_relname}"
  37
  38   make DESTDIR="${pkgdir}" install
  39
  40   install -D -m644 etc/META "${pkgdir}/usr/lib/ocaml/camlp5"
  41   install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/camlp5/LICENSE"
  42 }
  43