cherrytree/repos/community-x86_64/PKGBUILD

   1 # Maintainer: NicoHood <archlinux {cat} nicohood {dog} de>
   2 # PGP ID: 97312D5EB9D7AE7D0BD4307351DAE9B7C1AE9161
   3 # Contributor: Morgenstern <charles [at] charlesbwise [dot] com>
   4
   5 pkgname=cherrytree
   6 pkgver=0.99.54
   7 pkgrel=1
   8 pkgdesc="Hierarchical note-taking application"
   9 arch=('x86_64')
  10 url="https://www.giuspen.com/cherrytree/"
  11 license=('GPL3')
  12 depends=('fmt' 'gspell' 'gtksourceviewmm' 'libxml++2.6' 'uchardet' 'vte3')
  13 makedepends=('cmake' 'python' 'spdlog')
  14 checkdepends=('xorg-server-xvfb')
  15 source=("${pkgname}-${pkgver}.tar.xz::https://www.giuspen.com/software/${pkgname}_${pkgver}.tar.xz"
  16         "${pkgname}-${pkgver}.tar.xz.asc::https://www.giuspen.com/software/${pkgname}_${pkgver}.tar.xz.asc")
  17 sha512sums=('c4e8ff4440fc688ee6b24279857452e00f85614dcf094b311a768479fcc842712171e4dcd0b121b865aedd2d854ed5906e7fc615a69a76d50af71b91bb29835e'
  18             'SKIP')
  19 validpgpkeys=('C7BF38CE0BD442C2369AA984049128A20CE0648D') # Giuseppe Penone <giuspen [at] gmail [dot] com>
  20
  21 build() {
  22   cmake -B build -S "${pkgname}_${pkgver}" \
  23   -DINSTALL_GTEST:BOOL='OFF' \
  24   -DAUTO_RUN_TESTING:BOOL='OFF' \
  25   -DCMAKE_BUILD_TYPE='None' \
  26   -DCMAKE_INSTALL_PREFIX='/usr' \
  27   -Wno-dev
  28   cmake --build build
  29 }
  30
  31 check() {
  32   xvfb-run build/run_tests_with_x_1
  33   xvfb-run build/run_tests_with_x_2
  34 }
  35
  36 package() {
  37   DESTDIR="$pkgdir" cmake --install build
  38 }