geotag/trunk/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: Johannes Wienke <languitar at semipol dot de>
   3 # Contributor: Danilo Bargen <aur at dbrgn dot ch>
   4
   5 pkgname=geotag
   6 pkgver=0.103
   7 pkgrel=5
   8 pkgdesc='Match date/time information from photos with location information from a GPS unit or from a map'
   9 arch=('any')
  10 url='http://geotag.sourceforge.net/'
  11 license=('GPL')
  12 depends=('hicolor-icon-theme' 'java-runtime' 'perl-image-exiftool')
  13 optdepends=('dcraw: display preview for RAW images'
  14             'gpsbabel: load tracks from GPS')
  15 source=("https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.jar"
  16         'https://repo1.maven.org/maven2/javax/xml/bind/jaxb-api/2.3.1/jaxb-api-2.3.1.jar'
  17         "$pkgname.desktop"
  18         "$pkgname.appdata.xml"
  19         "$pkgname.sh")
  20 noextract=("$pkgname-$pkgver.jar")
  21 sha256sums=('9c12b0bdc8e497b461a5fb1611175e7c26750617febc70dd92b5c7783d69b2ba'
  22             '88b955a0df57880a26a74708bc34f74dcaf8ebf4e78843a28b50eae945732b06'
  23             '8bce60d5a6c8ac61a4e72f433fcb921cc4df7ded3ffb954838aedc07f9ae8c0a'
  24             'a0ed07e35fb3e632dc4aceb464d8c04e602847bf94f65854debf9ed36ebf3c93'
  25             '81ea7d4b35c85c7b032bfaba2caeb319ced2550692d4f739c68a94b741682066')
  26
  27 prepare() {
  28   bsdtar -xf $pkgname-$pkgver.jar images/$pkgname-128.png
  29 }
  30
  31 package() {
  32   install -Dm644 $pkgname-$pkgver.jar "$pkgdir/usr/share/java/$pkgname/$pkgname.jar"
  33   install -Dm644 jaxb-api-2.3.1.jar "$pkgdir/usr/share/java/$pkgname/lib/jaxb-api.jar"
  34   install -Dm755 $pkgname.sh "$pkgdir/usr/bin/$pkgname"
  35   install -Dm644 $pkgname.desktop "$pkgdir/usr/share/applications/$pkgname.desktop"
  36   install -Dm644 $pkgname.appdata.xml "$pkgdir"/usr/share/metainfo/$pkgname.appdata.xml
  37   install -Dm644 images/$pkgname-128.png "$pkgdir/usr/share/icons/hicolor/128x128/apps/$pkgname.png"
  38 }