gifski/trunk/PKGBUILD

   1 # Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
   2 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   3 # Contributor: Philipp Wolfer <ph.wolfer@gmail.com>
   4
   5 pkgname=gifski
   6 pkgver=1.11.0
   7 pkgrel=1
   8 pkgdesc='GIF encoder based on libimagequant (pngquant). Squeezes maximum possible quality from the awful GIF format.'
   9 arch=('x86_64')
  10 url='https://gif.ski'
  11 license=('AGPL3')
  12 depends=('ffmpeg')
  13 makedepends=('cargo' 'clang')
  14 source=("$pkgname-$pkgver.tar.gz::https://github.com/ImageOptim/$pkgname/archive/$pkgver.tar.gz")
  15 sha512sums=('9a150aace008034b1b50904fe8da7423118ddd905aa9cb661986135c98e331a5f61c293b4b75694dd7363c8a5605d06887d3781ee522318bba9b16e466fe42f0')
  16 options=('!lto')
  17
  18 prepare() {
  19   cd $pkgname-$pkgver
  20
  21   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  22 }
  23
  24
  25 build() {
  26   cd $pkgname-$pkgver
  27
  28   cargo build --frozen --release --features=video
  29 }
  30
  31 check() {
  32   cd $pkgname-$pkgver
  33
  34   cargo test --frozen
  35 }
  36
  37 package() {
  38   cd $pkgname-$pkgver
  39
  40   install -Dm 755 target/release/gifski "$pkgdir"/usr/bin/gifski
  41   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  42 }