libdispatch/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Contributor: Adrian Perez de Castro <aperez@igalia.com>
   3 pkgname=libdispatch
   4 pkgver=5.5.0
   5 pkgrel=1
   6 pkgdesc='Comprehensive support for concurrent code execution on multicore hardware'
   7 arch=('x86_64')
   8 url=https://apple.github.io/swift-corelibs-libdispatch
   9 license=('Apache')
  10 depends=('glibc')
  11 makedepends=('git' 'clang' 'cmake' 'ninja')
  12 provides=('libblocksruntime')
  13 source=("${pkgname}::git+https://github.com/apple/swift-corelibs-libdispatch.git#tag=swift-${pkgver%.0}-RELEASE"
  14         'remove-werror.patch'
  15         'avoid-libkqueue.patch')
  16 sha512sums=('SKIP'
  17             'd7d05ff6fa2ece40fea51e97f1af04e25ae9c2b55246fa2d753c446cff380262e611f9abb5112b7c7c94730362f0d06e0ccd867477c9470d1154e9c65e540529'
  18             '9f954538eee6ca63170c9fcf28cbcc090392360157c03bb33783789182102854ab344b432ff9f5603b873cb2540ffecf83458be559757eb094286cb41d9ba9ea')
  19
  20 prepare () {
  21         cd "${pkgname}"
  22         patch -p0 < "${srcdir}/remove-werror.patch"
  23         patch -p0 < "${srcdir}/avoid-libkqueue.patch"
  24 }
  25
  26 build () {
  27         cd "${pkgname}"
  28     export CC=clang
  29     export CXX=clang
  30         cmake \
  31         -Bbuild \
  32         -GNinja \
  33                 -DCMAKE_BUILD_TYPE=RelWithDebInfo \
  34                 -DCMAKE_INSTALL_PREFIX=/usr \
  35                 -DBlocksRuntime_INCLUDE_DIR=/usr/include \
  36                 -DBlocksRuntime_LIBRARIES=/usr/lib/libBlocksRuntime.so
  37         ninja -C build
  38 }
  39
  40 check () {
  41         cd "${pkgname}"
  42     ninja -C build test
  43 }
  44
  45 package () {
  46         cd "${pkgname}"
  47         DESTDIR="${pkgdir}" ninja -C build install
  48 }