libofx/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
   2 # Contributor: Aaron Griffin <aaron@archlinux.org>
   3
   4 pkgbase=libofx
   5 pkgname=('libofx' 'libofx-doc')
   6 pkgver=0.10.9
   7 pkgrel=1
   8 pkgdesc="API for the OFX banking standard"
   9 arch=('x86_64')
  10 url="https://github.com/libofx"
  11 license=('GPL')
  12 depends=('opensp' 'curl' 'libxml++2.6')
  13 checkdepends=('gnupg')
  14 source=(https://github.com/$pkgname/$pkgname/releases/download/$pkgver/$pkgname-$pkgver.tar.gz)
  15 sha256sums=('1ca89ff7d681c9edad312172ac464231a8de686e653213612f9417492cef0d37')
  16
  17 build() {
  18   cd $pkgbase-$pkgver
  19   ./configure --prefix=/usr
  20    sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  21    make CXXFLAGS+=-std=c++11
  22 }
  23
  24 check() {
  25   cd $pkgbase-$pkgver
  26   make check
  27 }
  28
  29 package_libofx() {
  30   options=('!docs')
  31
  32   cd $pkgbase-$pkgver
  33   make DESTDIR="$pkgdir" install
  34 }
  35
  36 package_libofx-doc() {
  37   pkgdesc="Documention of the OFX banking standard API"
  38   depends=()
  39
  40   cd $pkgbase-$pkgver
  41   make DESTDIR="$pkgdir" install-docDATA
  42   make -C doc DESTDIR="$pkgdir" install
  43 }