owl-lisp/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 pkgname=owl-lisp
   4 pkgver=0.2.1
   5 pkgrel=1
   6 pkgdesc='Simple purely functional lisp'
   7 url='https://gitlab.com/owl-lisp/owl.git'
   8 arch=('x86_64')
   9 license=('MIT')
  10 depends=('glibc')
  11 makedepends=('pandoc')
  12 source=(https://gitlab.com/owl-lisp/owl/-/archive/v${pkgver}/owl-v${pkgver}.tar.gz)
  13 sha256sums=('4a8dd3cce411b64ffbea98357f705a91ff900318d035ffb899fc49068b554e75')
  14 b2sums=('082b86b7b233933c78059971b9820a63442ceef74fa6ba82a5afa6068f254f295a187ba928e8e255077d97d9c82710aa94f77717ba328e68e15ade2dd0c9ec6b')
  15
  16 prepare() {
  17   cd owl-v${pkgver}
  18
  19   # support distro CFLAGS and CPPFLAGS
  20   sed -e '/export CFLAGS/d' -e '/CFLAGS =/d' \
  21       -e 's|$(CFLAGS)|$(CFLAGS) $(CPPFLAGS)|g' -i Makefile
  22
  23   # make build reproducible, we compress ourselves
  24   sed -e 's|gzip -9|@echo|g' -e 's|\.gz||g' -i Makefile
  25
  26   # fix missing Makefile entry
  27   sed 's|manual.md:|manual.md: bin/ol|' -i Makefile
  28
  29   # remove failing tests (can't run inside makepkg)
  30   rm tests/getpid.sh
  31 }
  32
  33 build() {
  34   cd owl-v${pkgver}
  35   make owl documentation
  36 }
  37
  38 check() {
  39   cd owl-v${pkgver}
  40   make -j1 test fasltest
  41 }
  42
  43 package() {
  44   cd owl-v${pkgver}
  45   make DESTDIR="${pkgdir}" install
  46   install -Dm 644 fasl/* -t "${pkgdir}/var/lib/${pkgname}/fasl"
  47   install -Dm 644 LICENCE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  48   install -Dm 644 README.md doc/manual.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  49 }
  50
  51 # vim: ts=2 sw=2 et: