python-flask-cors/trunk/PKGBUILD

   1 # Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
   2 # Maintainer: Johannes Löthberg <johannes@kyriasis.com>
   3
   4 pkgname=python-flask-cors
   5 pkgver=3.0.10
   6 pkgrel=5
   7
   8 pkgdesc='A Flask extension adding a decorator for CORS support'
   9 url='https://pypi.org/project/Flask-Cors'
  10 arch=('any')
  11 license=('MIT')
  12
  13 depends=('python-flask' 'python-six')
  14 makedepends=('python-setuptools')
  15
  16 source=("https://pypi.org/packages/source/F/Flask-Cors/Flask-Cors-$pkgver.tar.gz")
  17
  18 sha256sums=('b60839393f3b84a0f3746f6cdca56c1ad7426aa738b70d6c61375857823181de')
  19
  20 build() {
  21         cd Flask-Cors-$pkgver
  22         python setup.py build
  23 }
  24
  25 check() {
  26         cd Flask-Cors-$pkgver
  27         # Upstream uses nosetests, which appears to test all Pyton files,
  28         # while unittest discovers test*.py only by default.
  29         python -m unittest discover -p '*test*.py'
  30 }
  31
  32 package() {
  33         cd Flask-Cors-$pkgver
  34         python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  35         install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  36 }