python-fqdn/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=python-fqdn
   4 pkgver=1.5.1
   5 pkgrel=2
   6 pkgdesc='RFC-compliant FQDN validation and manipulation for Python'
   7 arch=('any')
   8 url='https://github.com/ypcrts/fqdn'
   9 license=('MPL2')
  10 depends=('python')
  11 makedepends=(
  12   'git'
  13   'python-build'
  14   'python-installer'
  15   'python-wheel'
  16   'python-setuptools'
  17 )
  18 checkdepends=('python-pytest')
  19 _commit='3a4feda3414bde7b3386e995ed1d2ed36607d4cf'
  20 source=("$pkgname::git+$url#commit=$_commit")
  21 b2sums=('SKIP')
  22
  23 pkgver() {
  24   cd "$pkgname"
  25
  26   git describe --tags | sed 's/^v//'
  27 }
  28
  29 build() {
  30   cd "$pkgname"
  31
  32   python -m build --wheel --no-isolation
  33 }
  34
  35 check() {
  36   cd "$pkgname"
  37
  38   pytest -v
  39 }
  40
  41 package() {
  42   cd "$pkgname"
  43
  44   python -m installer --destdir="$pkgdir" dist/*.whl
  45
  46   # documentation
  47   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.rst
  48 }