python-micawber/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2
   3 _name=micawber
   4 pkgname=python-micawber
   5 pkgver=0.5.4
   6 pkgrel=4
   7 pkgdesc="A small library for extracting rich content from urls."
   8 arch=('any')
   9 url="https://github.com/coleifer/micawber"
  10 license=('MIT')
  11 depends=('python')
  12 makedepends=('python-setuptools')
  13 checkdepends=('python-pytest' 'python-beautifulsoup4' 'python-django')
  14 optdepends=('python-django: django support'
  15             'python-flask: flask support'
  16             'python-redis: redis caching support')
  17 source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
  18 sha512sums=('7419af024de7a917d8fc8aea75cb2cbb9f03f5fce73e040a420f7ffd3f950e5717348a252f9716b42bf979757f5ba43d82239a88df5f904964b2157f179aac8e')
  19 b2sums=('cc31aaa6b72ad4c4d1032792a3748d95edda2af2e233dc69f362d25d2cda8ddf25ca7b9fdaea71685c7fa9bf3eaf571bec748451eba1b913477d0490c63b3334')
  20
  21 prepare() {
  22   mv -v "${_name}-$pkgver" "$pkgname-$pkgver"
  23 }
  24
  25 build() {
  26   cd "$pkgname-$pkgver"
  27   python setup.py build
  28 }
  29
  30 check() {
  31   cd "$pkgname-$pkgver"
  32   export PYTHONPATH="build/lib:${PYTHONPATH}"
  33   python runtests.py
  34 }
  35
  36 package() {
  37   cd "$pkgname-$pkgver"
  38   python setup.py install --skip-build \
  39                           --optimize=1 \
  40                           --root="${pkgdir}"
  41   install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  42   install -vDm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
  43 }