python-versioneer/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=python-versioneer
   4 pkgver=0.28
   5 pkgrel=2
   6 pkgdesc='A tool for managing a recorded version number in setuptools-based python projects'
   7 arch=('any')
   8 url='https://github.com/python-versioneer/python-versioneer'
   9 license=('custom:Unlicense')
  10 depends=('python' 'python-setuptools' 'python-tomli') # tomli: remove once we move to python 3.11
  11 makedepends=(
  12   'git'
  13   'python-build'
  14   'python-installer'
  15   'python-wheel'
  16 )
  17 _commit='83f20fdf886df7a6089fca3bb7fc3c33198bd629'
  18 source=("$pkgname::git+$url#commit=$_commit")
  19 b2sums=('SKIP')
  20
  21 pkgver() {
  22   cd "$pkgname"
  23
  24   git describe --tags | sed 's/^v//'
  25 }
  26
  27 build() {
  28   cd "$pkgname"
  29
  30   python -m build --wheel --no-isolation
  31 }
  32
  33 check() {
  34   cd "$pkgname"
  35
  36   python setup.py make_versioneer
  37   python -m unittest discover test
  38 }
  39
  40 package() {
  41   cd "$pkgname"
  42
  43   python -m installer --destdir="$pkgdir" dist/*.whl
  44
  45   # license
  46   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  47 }