python-xlsxwriter/trunk/PKGBUILD

   1 # Maintainer: Andrzej Giniewicz <gginiu@gmail.com>
   2 # Contributor: George Rawlinson <grawlinson@archlinux.org>
   3
   4 pkgname=python-xlsxwriter
   5 pkgver=3.1.0
   6 pkgrel=1
   7 pkgdesc='A Python module for creating Excel XLSX files'
   8 arch=('any')
   9 url='https://github.com/jmcnamara/XlsxWriter'
  10 license=('BSD')
  11 depends=('python')
  12 makedepends=(
  13   'git'
  14   'python-build'
  15   'python-installer'
  16   'python-wheel'
  17   'python-setuptools'
  18 )
  19 _commit='f6c4ff2335a6439b800c45750ab840e560585cce'
  20 source=("$pkgname::git+$url#commit=$_commit")
  21 b2sums=('SKIP')
  22
  23 pkgver() {
  24   cd "$pkgname"
  25
  26   git describe --tags | sed 's/^RELEASE_//'
  27 }
  28
  29 build() {
  30   cd "$pkgname"
  31
  32   python -m build --wheel --no-isolation
  33 }
  34
  35 check() {
  36   cd "$pkgname"
  37
  38   python -m unittest discover
  39 }
  40
  41 package() {
  42   cd "$pkgname"
  43
  44   python -m installer --destdir="$pkgdir" dist/*.whl
  45
  46   # license
  47   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.txt
  48 }