ruby-hitimes/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Olivier Biesmans <olivier at biesmans dot fr>
   3
   4 _gemname=hitimes
   5 pkgname=ruby-${_gemname}
   6 pkgver=2.0.0
   7 pkgrel=3
   8 pkgdesc='Fast, high resolution timer library for recording performance metrics'
   9 url='https://github.com/copiousfreetime/hitimes'
  10 arch=('x86_64')
  11 license=('ISC')
  12 depends=('ruby')
  13 makedepends=('ruby-rdoc')
  14 options=('!emptydirs')
  15 source=(https://github.com/copiousfreetime/hitimes/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  16 sha256sums=('3cc6f67fd1e87f7978e8919c4af528a9f1677d8d70209b2bb46d6a196f26ad37')
  17 sha512sums=('ac7211eafe8e1534d65a26b235e2558712ce91ecfb529a097974e749ef07d4ae232cd10411561f4f759df920b3133b8a57089c7f77d5a0bd5a0b56352724fae7')
  18
  19 prepare() {
  20   cd ${_gemname}-${pkgver}
  21   sed -r "s|(s.version =) \".+\"|\1 \"${pkgver}\"|g" -i ${_gemname}.gemspec
  22 }
  23
  24 build() {
  25   cd ${_gemname}-${pkgver}
  26   gem build ${_gemname}.gemspec
  27 }
  28
  29 package() {
  30   cd ${_gemname}-${pkgver}
  31   local _gemdir="$(gem env gemdir)"
  32   gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" \
  33     -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
  34
  35   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  36   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  37   cp -r examples "${pkgdir}/usr/share/doc/${pkgname}"
  38
  39   cd "${pkgdir}/${_gemdir}"
  40   rm -rf cache gems/${_gemname}-${pkgver}/{ext,lib/*/*.so} \
  41     extensions/*/*/${_gemname}-${pkgver}/{mkmf.log,gem_make.out}
  42 }
  43
  44 # vim: ts=2 sw=2 et: