ruby-minitest-retry/trunk/PKGBUILD

   1 # Maintainer: Tim Meusel <tim@bastelfreak.de>
   2
   3 _gemname='minitest-retry'
   4 pkgname="ruby-${_gemname}"
   5 pkgver=0.2.2
   6 pkgrel=1
   7 pkgdesc='re-run the test when the test fails'
   8 arch=('any')
   9 url='https://github.com/y-yagi/minitest-retry'
  10 license=('MIT')
  11 depends=('ruby' 'ruby-minitest')
  12 makedepends=('ruby-rake' 'ruby-bundler')
  13 checkdepends=()
  14 options=('!emptydirs')
  15 source=("${url}/archive/v${pkgver}/${_gemname}-v${pkgver}.tar.gz")
  16 sha512sums=('c49620387999894742fb92a399440756eac046f7aa179dbf084e77cc2a43260bff7f5d012c2140062da8785b9592bedf6e6b38692fbd7753dd3d15fc5ca932a1')
  17
  18 prepare() {
  19   cd "${srcdir}/${_gemname}-${pkgver}"
  20   # allow latest dependencies
  21   sed --in-place 's|`git ls-files -z`|`find . -print0`|' "${_gemname}.gemspec"
  22
  23   # drop useless dependency
  24   sed --in-place '/bundler/d' Rakefile "${_gemname}.gemspec"
  25   sed --in-place '/pry/d' Gemfile test/test_helper.rb
  26 }
  27
  28 build() {
  29   cd "${srcdir}/${_gemname}-${pkgver}"
  30   gem build "${_gemname}.gemspec"
  31 }
  32
  33 check() {
  34   cd "${srcdir}/${_gemname}-${pkgver}"
  35   rake test
  36 }
  37
  38 package() {
  39 cd "${srcdir}/${_gemname}-${pkgver}"
  40   local _gemdir="$(gem env gemdir)"
  41   gem install --verbose --ignore-dependencies --no-user-install --install-dir "${pkgdir}/${_gemdir}" --bindir "${pkgdir}/usr/bin" "${_gemname}-${pkgver}.gem"
  42
  43   install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}/"
  44
  45   install -Dm 644 README.md CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  46
  47   rm -rf "${pkgdir}/${_gemdir}/cache"
  48  }