sscg/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Jelle van der Waa <jelle@archlinux.org>
   2
   3 pkgname=sscg
   4 pkgver=3.0.3
   5 pkgrel=1
   6 pkgdesc="Simple Signed Certificate Generator"
   7 url="https://github.com/sgallagher/sscg"
   8 license=('GPL')
   9 arch=(x86_64)
  10 depends=(openssl popt talloc ding-libs)
  11 makedepends=(git help2man meson)
  12 source=(git+https://github.com/sgallagher/sscg.git?signed#tag=${pkgname}-${pkgver})
  13 # https://github.com/sgallagher.gpg
  14 validpgpkeys=('850A9DD1DBF2ACCC6FC4949145DB85A568286D11')
  15 sha512sums=('SKIP')
  16
  17 build() {
  18   cd $pkgname
  19   meson --prefix=/usr \
  20         --buildtype plain \
  21         --auto-features enabled \
  22         -D b_lto=true \
  23         -D b_pie=true \
  24   build
  25   ninja -C build
  26 }
  27
  28 check() {
  29   cd $pkgname
  30   meson test -C build --print-errorlogs
  31 }
  32
  33 package() {
  34   cd $pkgname
  35   DESTDIR="${pkgdir}" meson install -C build
  36 }