tp_smapi-lts/trunk/PKGBUILD

   1 # Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
   2 # Contributor: xduugu
   3 # Contributor: nh2
   4 # Contributor: Steven Davidovitz <steviedizzle ð gmail đ com>
   5 # Contributor: Nick B <Shirakawasuna ð gmail đ com>
   6 # Contributor: Christof Musik <christof ð senfdax đ de>
   7 # Contributor: Stefan Rupp <archlinux ð stefanrupp đ de>
   8 # Contributor: Ignas Anikevicius <anikevicius ð gmail đ com>
   9
  10 pkgname=tp_smapi-lts
  11 pkgver=0.43
  12 pkgrel=316
  13 pkgdesc="Modules for ThinkPad's SMAPI functionality"
  14 arch=('x86_64')
  15 url='https://github.com/evgeni/tp_smapi'
  16 license=('GPL')
  17 makedepends=('linux-lts-headers' 'git')
  18 _commit=a63729ab30d85430048f65c37f29188ab484cd52  # tags/tp-smapi/0.43
  19 source=("git+https://github.com/evgeni/tp_smapi#commit=$_commit")
  20 sha256sums=('SKIP')
  21
  22 pkgver() {
  23   cd tp_smapi
  24   git describe --tags | sed 's/^tp-smapi\///;s/-/+/g'
  25 }
  26
  27 build() {
  28   cd tp_smapi
  29
  30   # https://bugs.archlinux.org/task/54975 (kernel has no _GLOBAL_OFFSET_TABLE_):
  31   # Clear EXTRA_CFLAGS since it defaults to injecting CFLAGS and -fno-plt breaks the modules
  32
  33   make HDAPS=1 KVER="$(</usr/src/linux-lts/version)" EXTRA_CFLAGS=
  34 }
  35
  36 package() {
  37   depends=('linux-lts')
  38
  39   local extradir=/usr/lib/modules/$(</usr/src/linux-lts/version)/extramodules
  40   cd tp_smapi
  41
  42   # install kernel modules
  43   find . -name "*.ko" -exec install -Dt "$pkgdir$extradir" {} +
  44
  45   # compress kernel modules
  46   find "$pkgdir" -name "*.ko" -exec xz {} +
  47
  48   # load module on startup
  49   echo tp_smapi | install -Dm644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/$pkgname.conf"
  50 }