volumeicon/trunk/PKGBUILD

   1 # Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
   2 # Contributor: Maato <maato softwarebakery com>
   3
   4 pkgname=volumeicon
   5 pkgver=0.5.1
   6 pkgrel=5
   7 pkgdesc='Volume control for the system tray'
   8 arch=(x86_64)
   9 url='https://softwarebakery.com/maato/volumeicon.html'
  10 license=(GPL3)
  11 depends=(alsa-lib gtk3 libnotify)
  12 makedepends=(git intltool)
  13 install=volumeicon.install
  14 source=("git+https://github.com/Maato/volumeicon.git#tag=$pkgver"
  15         "volumeicon-notify.patch::https://github.com/Maato/volumeicon/commit/78a9c23775ebe12d3f3be93c0798144a6e732d90.patch"
  16         volumeicon.desktop)
  17 sha256sums=('SKIP'
  18             'f9d7d14e302f760815bb0da2af7f00ae3f2ef34da69e84863ae3e97e7302b8db'
  19             '3f989bce3a080b2446af6d7ed7e8a22dfd3019f888a7b11a0759bf7cf704f975')
  20
  21 prepare() {
  22   cd $pkgname
  23   patch -Np1 -i ../volumeicon-notify.patch
  24   ./autogen.sh
  25 }
  26
  27 build() {
  28   cd $pkgname
  29   ./configure --prefix=/usr --enable-notify
  30   make
  31 }
  32
  33 package() {
  34   make -C $pkgname DESTDIR="$pkgdir" install
  35   install -Dm644 volumeicon.desktop "$pkgdir/usr/share/applications/volumeicon.desktop"
  36 }
  37
  38 # vim: ts=2 sw=2 et: